Last edit by diizuka at 4 Oct 2020, 08:22 AM

Last edit by DAVID at 3 Oct 2020, 07:54 PM

Last edit by diizuka at 5 Oct 2020, 01:48 PM

// Read BK3231S formware
// Tested on ESP8266.
// Using ESP32, ATMega328 may work.
#include <SPI.h>

#define PIN_CS 5 // GPIO5
#define FLASH_WRITE 0x02
#define FLASH_READ  0x03
#define READ_LEN 256

static void initSPI(){
  SPI.begin();
  SPI.setClockDivider(SPI_CLOCK_DIV128); // SPI_CLOCK_DIV2
  SPI.setDataMode(SPI_MODE3);
  SPI.setBitOrder(MSBFIRST);
  pinMode(PIN_CS, OUTPUT);
  digitalWrite(PIN_CS, 1);
}

static void readFromFlash(uint32_t addr, uint8_t* buf, uint32_t length) {
  digitalWrite(PIN_CS, 0);
  SPI.transfer(FLASH_READ);
  SPI.transfer(addr >> 16 & 0xff);
  SPI.transfer(addr >> 8 & 0xff);
  SPI.transfer(addr & 0xff);
  for (uint32_t offset = 0 ; offset < length ; offset++) {
    buf[offset] = SPI.transfer(0);
  }
  digitalWrite(PIN_CS, 1);
}

static void printToSerial(uint32_t addr, uint8_t* data, uint32_t length){
  for (uint32_t offset = 0; offset < length; offset += 16) {
    int ad = addr + offset;
    Serial.print((ad >> 20) & 0xf, HEX);
    Serial.print((ad >> 16) & 0xf, HEX);
    Serial.print((ad >> 12) & 0xf, HEX);
    Serial.print((ad >> 8) & 0xf, HEX);
    Serial.print((ad >> 4) & 0xf, HEX);
    Serial.print((ad >> 0) & 0xf, HEX);
    
    for (int i = 0 ; i < 16 ; i++) {
      uint8_t d = data[i + offset];
      Serial.print(" ");
      Serial.print((d >> 4) & 0x0f, HEX);
      Serial.print((d >> 0) & 0x0f, HEX);
    }
    Serial.print("\n");
  }
}

void setup() {
  initSPI();
  Serial.begin(115200);  
  while (!Serial) {} // wait for serial becomes ready
  Serial.print("\n");
  delay(10); // wait for BK3231S becomes ready
}

static uint32_t addr = 0;
void loop() {
  if (addr >= 0x00040000L) {
    return;
  }
  uint8_t buf[READ_LEN];
  readFromFlash(addr, buf, READ_LEN);
  printToSerial(addr, buf, READ_LEN);
  addr += READ_LEN;
  delay(100); // fix serial transfer timing difference
}

#!/usr/bin/python3
f = open("arm.bin", "wb")
while True:
        line = input()
        line = line[7:] # omit address
        r = line.split() # to array of string
        count = 0
        for c in r:
                m = count % 34
                count += 1
                if m == 32 or m == 33:
                    continue
                x = int(c, 16) # to number
                y = x.to_bytes(1, byteorder='little') # to binary
                f.write(y)

Last edit by diizuka at 10 Oct 2020, 01:58 PM

Last edit by diizuka at 11 Oct 2020, 02:54 PM

Last edit by iscle at 23 Jan 2021, 01:51 AM